[Xmonad] i18n in xprompt

[Andrea Rossato]

On Fri, Oct 05, 2007 at 02:51:17PM +0200, Andrea Rossato wrote:

I forgot the attachment...;)
-------------- next part --------------
-----------------------------------------------------------------------------
-- |
-- Module      :  XMonadContrib.IShellPrompt
-- Copyright   :  (C) 2007 Andrea Rossato
-- License     :  BSD3
-- 
-- Maintainer  :  andrea.rossato at unibz.it
-- Stability   :  unstable
-- Portability :  unportable
--
-- A i18n aware shell prompt for XMonad
--
-----------------------------------------------------------------------------

module XMonadContrib.IShellPrompt (
                             -- * Usage
                             -- $usage
                             ishellPrompt
                              ) where

import XMonad
import XMonadContrib.IXPrompt
import XMonadContrib.IXPromptLib
import XMonadContrib.Dmenu

import Control.Monad
import Data.List
import System.Directory
import System.IO
import System.Environment

-- $usage
--
-- 1. In Config.hs add:
--
-- > import XMonadContrib.IXPrompt
-- > import XMonadContrib.IShellPrompt
--
-- 2. add XMonadContrib.IXPromptLib to the "other-modules" list in xmonad.cabal:
--
-- > other-modules:      Config Operations StackSet XMonad XMonadContrib.IXPromptLib
-- 
-- 3. In your keybindings add something like:
--
-- >   , ((modMask .|. controlMask, xK_x), ishellPrompt defaultXPConfig)
--

-- %import XMonadContrib.IXPrompt
-- %import XMonadContrib.IShellPrompt
-- %keybind , ((modMask .|. controlMask, xK_x), ishellPrompt defaultXPConfig)

data Shell = Shell

instance XPrompt Shell where
    showXPrompt Shell = "Run:   "


ishellPrompt :: X ()
ishellPrompt = mkXPrompt Shell defaultXPConfig getShellCompl spawn

getShellCompl :: String -> IO [String]
getShellCompl s 
    | s /= "" && last s /= ' ' = do
  s' <- toLocale s
  f <- fmap lines $ runProcessWithInput "/bin/bash" [] ("compgen -A file " ++ s' ++ "\n")
  c <- commandCompletionFunction s'
  hPutStrLn stdout s
  mapM fromLocale $ map escape . sort . nub $ f ++ c
    | otherwise = return []

commandCompletionFunction :: String -> IO [String]
commandCompletionFunction str 
    | '/' `elem` str = return []
    | otherwise      = do
  p <- getEnv "PATH"
  cl p
    where
      cl     = liftM (nub . rmPath . concat) . mapM cmpl . split ':'  
      cmpl s = filter (isPrefixOf str) `fmap` getFileNames s

getFileNames :: FilePath -> IO [FilePath]
getFileNames fp = 
    getDirectoryContents fp `catch` \_ -> return []

rmPath :: [String] -> [String]
rmPath s = 
    map (reverse . fst . break  (=='/') . reverse) s

split :: Eq a => a -> [a] -> [[a]]
split _ [] = []
split e l =
    f : split e (rest ls)
        where 
          (f,ls) = span (/=e) l
          rest s | s == [] = []
                 | otherwise = tail s

escape :: String -> String
escape []       = ""
escape (' ':xs) = "\\ " ++ escape xs
escape (x:xs)
    | isSpecialChar x = '\\' : x : escape xs
    | otherwise = x : escape xs

isSpecialChar :: Char -> Bool
isSpecialChar =  flip elem "\\@\"'#?$*()[]{};"